nixos-conf/shared/base.nix

{
  pkgs,
  lib,
  nixpkgs-flake,
  ...
}:
{
  options.custom.gua_pref = lib.mkOption {
    type = with lib.types; nullOr (strMatching "^[0-9a-zA-Z:]+$");
    default = null;
    description = "IPv6 GUA Prefix to use in other confs";
  };

  config = {
    custom.gua_pref = "2001:14ba:a090:39";

    ######################################## Packages ###############################################
    environment.systemPackages = with pkgs; [
      tmux
      git
      vim
      p7zip
      tree
      ripgrep
      btop
      dig
      termshark

      age
      minisign
      pwgen
      ssss
    ];

    ######################################## ZSH configuration ######################################
    users.defaultUserShell = pkgs.zsh;
    environment.shells = with pkgs; [ zsh ];
    programs.zsh = {
      enable = true;
      autosuggestions.enable = true;
      syntaxHighlighting.enable = true;
      ohMyZsh = {
        enable = true;
        plugins = [
          "history-substring-search"
          "tmux"
        ];
        theme = "af-magic";
      };
      interactiveShellInit = ''
        ZSH_TMUX_AUTOSTART=false
        ZSH_TMUX_AUTOQUIT=false
        ZSH_TMUX_CONFIG=/etc/tmux.conf
      '';
      promptInit = ''
        if [ "$SHLVL" != 1 ]; then 
          setopt PROMPT_SUBST
          RPROMPT+='[depth-''${SHLVL}]'
        fi
      '';
    };

    ######################################## tmux configuration #####################################
    programs.tmux.enable = true;
    programs.tmux.extraConfig = ''
      unbind C-b
      set -g prefix M-w
      bind M-w send-prefix

      bind s split-window -v
      bind v split-window -h

      # Smart pane switching with awareness of Vim splits.
      bind -n C-h run "(tmux display-message -p '#{pane_current_command}' | grep -iq nvim && tmux send-keys C-h) || tmux select-pane -L"
      bind -n C-j run "(tmux display-message -p '#{pane_current_command}' | grep -iq nvim && tmux send-keys C-j) || tmux select-pane -D"
      bind -n C-k run "(tmux display-message -p '#{pane_current_command}' | grep -iq nvim && tmux send-keys C-k) || tmux select-pane -U"
      bind -n C-l run "(tmux display-message -p '#{pane_current_command}' | grep -iq nvim && tmux send-keys C-l) || tmux select-pane -R"

      bind -n C-Left select-pane -L
      bind -n C-Right select-pane -R
      bind -n C-Up select-pane -U
      bind -n C-Down select-pane -D

      # resize panes more easily
      bind -r h resize-pane -L 10
      bind -r j resize-pane -D 10
      bind -r k resize-pane -U 10
      bind -r l resize-pane -R 10

      bind M-c attach -c "#{pane_current_path}" 

      set -s escape-time 0
    '';

    ######################################## SSH configuration #########################
    services.openssh = {
      enable = true;
      settings.PasswordAuthentication = false;
    };
    users.users.root.openssh.authorizedKeys.keys = [
      "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIJowj9IJIgYjDwZm5mEttiwvPfu1dd4eVTHfaDnbwcOV vili-bw-ssh-ed25519-main"
    ];

    ######################################## Localization ###########################################
    i18n.defaultLocale = "en_US.UTF-8";

    i18n.extraLocaleSettings = {
      LC_ADDRESS = "fi_FI.UTF-8";
      LC_IDENTIFICATION = "fi_FI.UTF-8";
      LC_MEASUREMENT = "fi_FI.UTF-8";
      LC_MONETARY = "fi_FI.UTF-8";
      LC_NAME = "fi_FI.UTF-8";
      LC_NUMERIC = "fi_FI.UTF-8";
      LC_PAPER = "fi_FI.UTF-8";
      LC_TELEPHONE = "fi_FI.UTF-8";
      LC_TIME = "fi_FI.UTF-8";
    };

    services.xserver.xkb = {
      layout = "us,";
      variant = "de_se_fi,";
    };
    console = lib.mkForce {
      font = "Lat2-Terminus16";
      useXkbConfig = true; # use xkbOptions in tty.
    };
    time.timeZone = "Europe/Helsinki";

    ######################################## Memory management ######################################
    zramSwap.enable = true;

    ######################################## Housekeeping ###########################################
    system.autoUpgrade = {
      enable = true;
      flake = ''"git+https://forgejo.sinerva.eu/VSinerva/nixos-conf.git?ref=main&shallow=1"'';
      dates = "04:00";
      randomizedDelaySec = "30min";
      allowReboot = true;
      rebootWindow = {
        lower = "03:30";
        upper = "05:00";
      };
    };

    nixpkgs.config.allowUnfree = true;
    nix = {
      registry = {
        nixpkgs.flake = nixpkgs-flake;
      };
      settings = {
        experimental-features = [
          "nix-command"
          "flakes"
        ];
        auto-optimise-store = true;
        substituters = [ "https://cache.sinerva.eu" ];
        trusted-public-keys = [ "cache.sinerva.eu:TaIhyAKozO/r88EBWMSdbp+TB0YlcXT/EADunYoYLVc=" ];
      };
      gc = {
        automatic = true;
        options = "--delete-older-than 3d";
        dates = "05:00";
        randomizedDelaySec = "30min";
      };
    };

    ######################################## Misc. ##################################################
    networking = {
      # Easiest to use and most distros use this by default.
      networkmanager = {
        enable = true;
        # Use EUI-64 addresses by default, so that addresses are predictable
        settings."connection"."ipv6.addr-gen-mode" = 0;
      };
      # IPv6 privacy addresses for outgoing traffic
      tempAddresses = "default";
    };

    users.mutableUsers = false; # Force all user management to happen throught nix-files

    boot.loader = {
      systemd-boot.enable = lib.mkDefault true;
      efi.canTouchEfiVariables = lib.mkDefault true;
      timeout = lib.mkDefault 0;
    };
  };
}